自动切换IP批处理命令

1.新建一个文本文档，把下面的代码复制进去，保存退出。

@echo off
color f0
echo.
echo 修改IP地址:
echo 1为自动获取IP地址
echo 2为修改成宿舍IP地址，为115.154.113.16 =_=!
echo 3为修改成实验室IP地址，为192.168.3.16
echo 4为自定义IP地址
echo.
set sel=
set/p sel=请选择修改方式：
if "%sel%"=="1" goto auto
if "%sel%"=="2" goto dorm
if "%sel%"=="3" goto lab
if "%sel%"=="4" goto coustom
echo 您没有选择修改方式。
goto end



:auto
cls
color 0e
echo 正在更改IP地址，请稍等......
netsh interface ip set address name="本地连接" source=dhcp
echo 正在更改DNS地址，请稍等......
netsh interface ip set dns name="本地连接" source=dhcp
echo 更改IP地址完成！
goto end



:dorm
cls
color 0e
echo 正在切换为宿舍IP地址，请稍等......
netsh interface ip set address 本地连接 static 115.154.113.16 255.0.0.0 115.154.113.1 gwmetric=1
echo 设置IP地址成功！
netsh interface ip set dns 本地连接 static 202.117.0.20
netsh interface ip add dns 本地连接 202.117.0.21
echo 设置DNS服务器成功！
echo.
echo 已切换为宿舍IP地址。
goto end



:lab
cls
color 0e
echo 正在切换为实验室IP地址，请稍等......
netsh interface ip set address 本地连接 static 192.168.3.16 255.255.255.0 192.168.3.1 gwmetric=1
echo 设置IP地址成功！
netsh interface ip set dns 本地连接 static 202.117.0.20
netsh interface ip add dns 本地连接 202.117.0.21
echo 设置DNS服务器成功！
echo.
echo 已切换为实验室IP地址。
goto end



:coustom
cls
color 1F
echo 下面将由你配置IP地址，请按提示顺序输入......
set ip_new=
set/p ip_new=请输入IP地址：

set mask_new=
set/p mask_new=请输入子网掩码：

set gw_new=
set/p gw_new=请输入默认网关：

netsh interface ip set address 本地连接 static addr=%ip_new% mask=%mask_new% gateway=%gw_new% gwmetric=1
echo 设置IP地址成功！
echo.
set dns1=
set/p dns1=请输入主DNS地址：
netsh interface ip set dns 本地连接 static %dns1%

set dns2=
set/p dns2=请输入备份DNS地址：
netsh interface ip add dns 本地连接 %dns2%
echo 设置DNS服务器成功！
echo.
echo IP地址配置完成。


:end
echo. & pause

2. 把文本文档的后缀名.txt改为.bat，变成批处理文件，双击打开就可以运行了。



红色部分注意换成自己的IP，仅供参考。