ansys荷载结构命令流

finish
/clear
/prep7

*set,shuxiang,276170 !竖向荷载
*set,zuoce,125500 !水平荷载
*set,youce,-125500

!*set,jizhongli,-100000 !地震集中力

*set,uxishu,136.966e6*0.5 !水平弹性抗力系数
*set,vxishu,87.4348e6*0.5 !竖向弹性抗力系数

!定义单元类型、实常数及材料性质
et,1,beam3
r,1,0.3,0.00225,0.3
mp,ex,1,3.1e10 !弹性模量
mp,dens,1,2500 !密度
mp,prxy,1,0.167 !泊松比

!创建几何模型 画点
k,1,0,2.55
k,2,-2.04,1.53
k,3,-2.6,-0.15
k,4,-2.319721,-2.023237
k,5,-1.648852,-2.71152
k,6,0,-2.98
k,7,1.648852,-2.71152
k,8,2.319721,-2.023237
k,9,2.6,-0.15
k,10,2.04,1.53
k,1000,0,0 !中心点

!画隧道轮廓线
larc,1,2,1000,2.55
larc,2,3,1000,2.8
larc,3,4,1000,6.4
larc,4,5,1000,1.04969
larc,5,6,1000,5.2
larc,6,7,1000,5.2
larc,7,8,1000,1.04969
larc,8,9,1000,6.4
larc,9,10,1000,2.8
larc,10,1,1000,2.55

!选择左边的所有线
allsel !选择所有的实体
lsel,s,loc,x,0,-5 !选择左边的所有线:x从0到－5
lcomb,all !合并所选的线
lesize,all,,,30 !把上面合并的线等分30段

!选择右边的所有线
allsel
lsel,s,loc,x,0,5
lcomb,all
lesize,all,,,30

allsel !全选

!划分单元
lmesh,all
nplot !显示节点


!加弹簧
!y方向
*do,i,23,40
PSPRNG,i,TRAN,vxishu,,-0.3,, , !tran-直线的
*enddo
PSPRNG,2,TRAN,vxishu,,-0.3,, , !固定结构用的


!x方向
*do,i,15,26
PSPRNG,i,TRAN,uxishu,-0.3,,, ,
*enddo

*do,i,37,48
PSPRNG,i,TRAN,uxishu,0.3,,, ,
*enddo

allsel
finish


!进入求解层，施加荷载，定义荷载步等
/solu

!施加约束
nsel,s,,,2 !选择约束的节点
!nsel,s,loc,x,0d
!nsel,r,loc,y,-2.98
d,all,ux !施加水平方向的约束


allsel
fcum,add,, !一定要，使荷载能叠加

!竖向荷载
*do,i,3,15
a=-shuxiang*0.5*abs(nx(i)-nx(i+1))
f,i+1,fy,a
f,i,fy,a
*enddo
*do,i,47,59
a=-shuxiang*0.5*abs(nx(i)-nx(i+1))
f,i+1,fy,a
f,i,fy,a
*enddo

!对未循环的节点施加竖向荷载
a=-shuxiang*0.5*abs(nx(1)-nx(3))
f,3,fy,a
f,1,fy,2*a
f,60,fy,a


!水平荷载
*do,i,3,30
a=zuoce*0.5*abs(ny(i)-ny(i+1))
f,i+1,fx,a
f,i,fx,a
*enddo
*do,i,32,59
a=youce*0.5*abs(ny(i)-ny(i+1))
f,i+1,fx,a
f,i,fx,a
*enddo

!f,1,fx,jizhongli !加集中力

!对未循环的节点施加水平荷载
a=youce*0.5*abs(ny(31)-ny(2))
f,31,fx,-a
f,32,fx,a

!施加重力
acel,,9.8

solve !求解
finish



!进入后处理，定义荷载工况并组合，输出图片和文本文件
/post1

!显示弯矩图
etable,mi,smisc,6
etable,mj,smisc,12
plls,mi,mj,-1

!显示轴力图
etable,fi,smisc,1
etable,fj,smisc,7
plls,fi,fj,1

!显示变形图
pldisp,1