ansys-桁架分析

finish$/cle !新建
/filname,truss,1 !定义工作文件名
/title,the analysis of plane truss !定义工作标题
/replot !重新显示
/prep7 !进入prep7处理器
k,1$k,2,6$k,3,12$k,4,18$k,5,24 !创建关键点
k,6,6,8$k,7,12,8$k,8,18,8
l,1,2$l,2,3$l,3,4$l,4,5$l,1,6$l,6,7 !创建线
l,7,8$l,5,8$l,2,6$l,3,7$l,4,8$l,6,3
l,3,8
/pnum,kp,1 !设置显示关键点号
/pnum,line,1 !设置显示线号
lplot !绘制线
et,1,link1!定义单元类型
r,1,0.01$r,2.0,0.005$r,3,0.0125!定义单元实常数
mp,ex,1,2.1e11 !定义材料属性
mp,prxy,1,0.3
!mp,ex,2,2.1e12
!mp,prxy,2,0.3
lsel,s,tan1,y$latt,1,1,1!选择水平线并定义属性
lsel,s,loc,y,1,7$lsel,r,loc,x,6,18$latt,1,2,1 !选择竖杆和中间斜杆并定义属性
lsel,s,loc,y,1,7$lsel,u,loc,x,6,18$latt,1,3,1 !选择两边斜杆并定义属性
allsel,all !选择全部实体
/pnum,real,1 !设置显示实常数号
/replot !显示各线的实常数号
lesize,all,,,1 !定义各个线所划分的单元个数
lmesh,all !对所有线进行单元划分
finish
!2.加载和求解
/solu !进入solu处理器
antype,0 !定义分析类型
lplot !绘制线
dk,1,ux,,,,uy !约束关键点1的ux，uy
dk,5,uy !约束关键点5的uy
fk,6,fy,-200000 !关键点6施加向下的荷载200000N
fk,8,fy,-200000 !关键点8施加向下的荷载200000N
fk,2,fy,-400000 !关键点2施加向下的荷载400000N
fk,3,fy,-400000 !关键点3施加向下的荷载400000N
fk,4,fy,-400000 !关键点4施加向下的荷载400000N
/pnum,real,0 !关闭实常数号显示
/pnum,line,0 !关闭线号显示
/pnum,kp,0 !关闭关键点号显示
/pbc,all,,1 !显示实体上的边界条件和荷载
/psymb,ldiv,-1 !关闭线划分单元属性显示
lplot !绘制线
solve !执行求解
finish
!3.后处理
/post1 !进入后处理器
pldisp !绘制变形图
etable,mforce,smisc,1 !定义单元轴力表
etable,mstress,ls,1 !定义单元应力表
plls,mfroce,mforce,1 !绘制单元轴力表
plls,mstress,mstress,1 !绘制单元应力图
prrsol !列出支撑反力表
finish